Blijbol.nl

Blijbol, de blije zaak

Links Over Blijbol Gastenboek

Home Nieuws Games Software Game Maker

25 keer gedownload

Kleurcontrastcontrole

Bepaal toegankelijkheid van kleurenpaar

Downloads

Lees alstublieft links de licentie.

v1.0
(8xp; < 0,01 MB)

Links naar hier:

Beschrijving

Voer twee kleuren in hexadecimale notatie in en controleer hun relatieve luminescenties en contrastverhouding, en of deze contrastverhouding voldoende is voor normale en grote tekst volgens de Web Content Accessibility Guidelins 2.0.

Tip: gebruik samen met Stelselconverter.

Codes

Licentie: Gebruik onderstaand programma op uw eigen risico. U mag deze broncode alleen aanpassen voor eigen gebruik. Aangepaste versies van dit programma kunnen niet worden gedistributeerd. De tekst 'Blijbol.nl' moet vanuit het programma duidelijk zichtbaar blijven. Copyright © 2011 Jeroen van der Gun.

`PROGRAM:CONTRAST`

:ClrHome
:Full
:Output(8,4,"Blijbol.nl
:Disp "
:Normal
:Fix 3
:1→J
:Input "C1=x",Str0
:Lbl 2
:If 3=length(Str0
:sub(Str0,1,1)+sub(Str0,1,1)+sub(Str0,2,1)+sub(Str0,2,1)+sub(Str0,3,1)+sub(Str0,3,1→Str0
:If 6≠length(Str0
:Goto 1
:0→L
:For(I,0,5
:inStrin"0123456789ABCDEF",sub(Str0,6-I,1
:If not(Ans
:Goto 1
:If fPart(I/2
:Then
:(X+16(Ans-1))/255
:If Ans≤.03928
:Then
:Ans/12.96
:Else
:((Ans+.055)/1.055)^2.4
:End
:If I=5
:.2126Ans
:If I=3
:.7152Ans
:If I=1
:.0722Ans
:L+Ans→L
:Else
:Ans-1→X
:End
:End
:If J=1
:Then
:Disp "L1="
:Output(3,4,Ans
:L→K
:2→J
:Input "C2=x",Str0
:Goto 2
:End
:Disp "L2="
:Output(5,4,Ans
:Fix 1
:(.05+max(K,L))/(.05+min(K,L
:Disp "Ratio="
:Output(6,7,Ans
:If Ans>7
:Then
:Disp "WCAG:AAA
:Else
:If Ans>4.5
:Then
:Disp "WCAG:AA-AAA
:Else
:If Ans>3
:Then
:Disp "WCAG:A-AA
:Else
:Disp "WCAG:A
:End
:End
:End
:Pause
:Lbl 0
:Float
:ClrHome
:Stop
:Lbl 1
:Menu("ERR:SYNTAX","Quit",0

Versie 1.0 (stabiel)

Releasedatum: 16 december 2011
Taal: Engels
Systeemeisen: Texas Instruments grafische rekenmachine draaiend op TI-83 Plus- of TI-84 Plus-besturingssysteem (Silver Edition is ook goed), 580 bytes vrij RAM-geheugen of archiefruimte voor opslag (tijdens gebruik is meer RAM-geheugen nodig)

Projectstatus

Een stabiele versie van dit product is uitgebracht. Het project is aangekondigd op 16 december 2011.

Credits

Dit hulpprogramma is gemaakt door Jeroen van der Gun.

Meer voor je rekenmachine

Software: Unixtijdconverter, Stelselconverter, Wrongs, Abc-formule
Games: Snake, Decoder, Connect4, Drop, Virus, 1000

Reacties

Er zijn nog geen reacties geplaatst. Gebruik het formulier om er een te plaatsen.